AlliedModders Wiki - User contributions [en]

Commands (SourceMod Scripting)

2013-06-14T20:08:31Z

Azelphur: Semicolons after if statements, someone dun goof'd.

[[SourceMod]] allows you to create console commands similar to [[AMX Mod X]]. There are two main types of console commands:
*'''Server Commands''' - Fired from one of the following input methods:
**the server console itself
**the remote console (RCON)
**the ServerCommand() function, either from SourceMod or the [[Half-Life 2]] engine
*'''Console Commands''' - Fired from one of the following input methods:
**a client's console
**any of the server command input methods

For server commands, there is no client index. For console/client commands, there is a client index, but it may be 0 to indicate that the command is from the server.

Note that button-bound "commands," such as +attack and +duck, are not actually console commands. They are a separate command stream sent over the network, as they need to be tied to a specific frame.

=Server Commands=
As noted above, server commands are fired through the server console, whether remote, local, or through the Source engine. There is no client index associated with a server command.

Server commands are registered through the <tt>RegServerCmd()</tt> function defined in <tt>console.inc</tt>. When registering a server command, you may be hooking an already existing command, and thus the return value is important.
*<tt>Plugin_Continue</tt> - The original server command will be processed, if there was one. If the server command was created by a plugin, this has no effect.
*<tt>Plugin_Handled</tt> - The original server command will not be processed, if there was one. If the server command was created by a plugin, this has no effect.
*<tt>Plugin_Stop</tt> - The original server command will not be processed, if there was one. Additionally, no further hooks will be called for this command until it is fired again.

==Adding Server Commands==
Let's say we want to add a test command to show how Half-Life 2 breaks down command arguments. A possible implementation might be
<pawn>
public OnPluginStart()
{
RegServerCmd("test_command", Command_Test);
}

public Action:Command_Test(args)
{
new String:arg[128];
new String:full[256];

GetCmdArgString(full, sizeof(full));

PrintToServer("Argument string: %s", full);
PrintToServer("Argument count: %d", args);
for (new i=1; i<=args; i++)
{
GetCmdArg(i, arg, sizeof(arg));
PrintToServer("Argument %d: %s", i, arg);
}
}
</pawn>

==Blocking Server Commands==
Let's say we wanted to disable the "kickid" command on the server. There's no real good reason to do this, but for example's sake:
<pawn>
public OnPluginStart()
{
RegServerCmd("kickid", Command_KickId);
}

public Action:Command_Kickid(args)
{
return Plugin_Handled;
}
</pawn>

=Console Commands=
Unlike server commands, console commands can be triggered by either the server or the client, so the callback function receives a client index as well as the argument count. If the server fired the command, the client index will be 0.

When returning the <tt>Action</tt> from the callback, the following effects will happen:
*<tt>Plugin_Continue</tt>: The original functionality of the command (if any) will still be processed. If there was no original functionality, the client will receive "Unknown command" in their console.
*<tt>Plugin_Handled</tt>: The original functionality of the command (if any) will be blocked. If there was no functionality originally, this prevents clients from seeing "Unknown command" in their console.
*<tt>Plugin_Stop</tt>: Same as <tt>Plugin_Handled</tt>, except that this will be the last hook called.

Note that, unlike AMX Mod X, SourceMod does not allow you to register command filters. I.e., there is no equivalent to this notation:
<pawn>register_clcmd("say /ff", "Command_SayFF");</pawn>

This notation was removed to make our internal code simpler and faster. Writing the same functionality is easy, and demonstrated below.

==Adding Commands==
Adding client commands is very simple. Let's port our earlier testing command to display information about the client as well.

<pawn>public OnPluginStart()
{
RegConsoleCmd("test_command", Command_Test);
}

public Action:Command_Test(client, args)
{
new String:arg[128];
new String:full[256];

GetCmdArgString(full, sizeof(full));

if (client)
{
PrintToServer("Command from client: %N", name);
} else {
PrintToServer("Command from server.");
}

PrintToServer("Argument string: %s", full);
PrintToServer("Argument count: %d", args);
for (new i=1; i<=args; i++)
{
GetCmdArg(i, arg, sizeof(arg));
PrintToServer("Argument %d: %s", i, arg);
}
}</pawn>

==Hooking Commands==
A common example is hooking the say command. Let's say we want to tell players whether FF is enabled when they say '/ff' in game.

Before we implement this, a common point of confusion with the 'say' command is that Half-Life 2 (and Half-Life 1), by default, send it with the text in one big quoted string. This means if you say "I like hot dogs," your command will be broken down as such:
*Argument string: "I like hot dogs"
*Argument count: 1
*Argument #1: I like hot dogs

However, if a player types this in their console: <tt>say I like yams</tt>, it will be broken up as:
*Argument string: I like yams
*Argument count: 3
*Argument #1: I
*Argument #2: like
*Argument #3: yams

Thus, to take into account both of these situations, we are going to use <tt>GetCmdArgString</tt> and manually parse the input.

<pawn>new Handle:ff = INVALID_HANDLE;

public OnPluginStart()
{
AddCommandListener(Command_Say, "say");
AddCommandListener(Command_Say, "say2");
AddCommandListener(Command_Say, "say_team");

ff = FindConVar("mp_friendlyfire");
}

public Action:Command_Say(client, const String:command[], argc)
{
decl String:text[192];
new startidx = 0;
if (GetCmdArgString(text, sizeof(text)) < 1)
{
return Plugin_Continue;
}

if (text[strlen(text)-1] == '"')
{
text[strlen(text)-1] = '\0';
startidx = 1;
}

if (strcmp(command, "say2", false) == 0)
startidx += 4;

if (strcmp(text[startidx], "ff", false) == 0)
{
if (ff != INVALID_HANDLE)
{
if (GetConVarBool(ff))
{
PrintToChat(client, "Friendly fire is enabled.");
} else {
PrintToChat(client, "Friendly fire is disabled.");
}
/* Block the client's messsage from broadcasting */
return Plugin_Handled;
}
}

/* Let say continue normally */
return Plugin_Continue;
}</pawn>

==Creating Admin Commands==
Let's create a simple admin command which kicks another player by their full name.

<pawn>public OnPluginStart()
{
RegAdminCmd("admin_kick",
Command_Kick,
ADMFLAG_KICK,
"Kicks a player by name");
}

public Action:Command_Kick(client, args)
{
if (args < 1)
{
PrintToConsole(client, "Usage: admin_kick <name>");
return Plugin_Handled;
}

new String:name[32], target = -1;
GetCmdArg(1, name, sizeof(name));

for (new i=1; i<=MaxClients; i++)
{
if (!IsClientConnected(i))
{
continue;
}
decl String:other[32];
GetClientName(i, other, sizeof(other));
if (StrEqual(name, other))
{
target = i;
}
}

if (target == -1)
{
PrintToConsole(client, "Could not find any player with the name: \"%s\"", name);
return Plugin_Handled;
}

ServerCommand("kickid %d", GetClientUserId(target));

return Plugin_Handled;
}</pawn>

==Immunity==
In our previous example, we did not take immunity into account. Immunity is a much more complex system in SourceMod than it was in AMX Mod X, and there is no simple flag to denote its permissions. Instead, two functions are provided:
*<tt>CanAdminTarget</tt>: Tests raw AdminId values for immunity.
*<tt>CanUserTarget</tt>: Tests in-game clients for immunity.

While immunity is generally tested ''player versus player'', it is possible you might want to check for immunity and not have a targetting client. While there is no convenience function for this yet, a good idea might be to check for either ''default'' or ''global'' immunity on the player's groups (these can be user-defined for non-player targeted scenarios).

When checking for immunity, the following heuristics are performed in this exact order:
<ol><li>If the targeting AdminId is <tt>INVALID_ADMIN_ID</tt>, targeting fails.</li>
<li>If the targetted AdminId is <tt>INVALID_ADMIN_ID</tt>, targeting succeeds.</li>
<li>If the targeting admin has <tt>Admin_Root</tt> (<tt>ADMFLAG_ROOT</tt>), targeting succeeds.</li>
<li>If the targetted admin has global immunity, targeting fails.</li>
<li>If the targetted admin has default immunity, and the targeting admin belongs to no groups, targeting fails.</li>
<li>If the targetted admin has specific immunity from the targeting admin via group immunities, targeting fails.</li>
<li>If no conclusion is reached via the previous steps, targeting succeeds.</li>
</ol>

So, how can we adapt our function about to use immunity?

<pawn>public Action:Command_Kick(client, args)
{
if (args < 1)
{
PrintToConsole(client, "Usage: admin_kick <name>");
return Plugin_Handled;
}

new String:name[32], target = -1;
GetCmdArg(1, name, sizeof(name));

for (new i=1; i<=MaxClients; i++)
{
if (!IsClientConnected(i))
{
continue;
}
decl String:other[32];
GetClientName(i, other, sizeof(other));
if (StrEqual(name, other))
{
target = i;
}
}

if (target == -1)
{
PrintToConsole(client, "Could not find any player with the name: \"%s\"", name);
return Plugin_Handled;
}

if (!CanUserTarget(client, target))
{
PrintToConsole(client, "You cannot target this client.");
return Plugin_Handled;
}

ServerCommand("kickid %d", GetClientUserId(target));

return Plugin_Handled;
}</pawn>

=Client-Only Commands=
SourceMod exposes a forward that is called whenever a client executes any command string in their console, called <tt>OnClientCommand</tt>. An example of this looks like:

<pawn>public Action:OnClientCommand(client, args)
{
new String:cmd[16];
GetCmdArg(0, cmd, sizeof(cmd)); /* Get command name */

if (StrEqual(cmd, "test_command"))
{
/* Got the client command! Block it... */
return Plugin_Handled;
}

return Plugin_Continue;
}</pawn>

It is worth noting that not everything a client sends will be available through this command. Command registered via external sources in C++ may not be available, especially if they are created via <tt>CON_COMMAND</tt> in the game mod itself. For example, "say" is usually implemented this way, because it can be used by both clients and the server, and thus it does not channel through this forward.

=Chat Triggers=
SourceMod will automatically create chat triggers for every command you make. For example, if you create a console command called <tt>"sm_megaslap"</tt>, administrators will be able to type any of the following commands in <tt>say</tt>/<tt>say_team</tt> message modes:
<pre>!sm_megaslap
!megaslap
/sm_megaslap
/megaslap</pre>

SourceMod then executes this command and its arguments as if it came from the client console.
*"<tt>!</tt>" is the default ''public'' trigger (<tt>PublicChatTrigger</tt> in <tt>configs/core.cfg</tt>) and your entry will be displayed to all clients as normal.
*"<tt>/</tt>" is the default ''silent'' trigger (<tt>SilentChatTrigger</tt> in <tt>configs/core.cfg</tt>) and your entry will be blocked from being displayed.

SourceMod will only execute commands registered with <tt>RegConsoleCmd</tt> or <tt>RegAdminCmd</tt>, and only if those commands are not already provided by Half-Life 2 or the game mod. If the command is prefixed with "sm_" then the "sm_" can be omitted from the chat trigger.

Console commands which wish to support usage as a chat trigger should not use <tt>PrintTo*</tt> natives. Instead, they should use <tt>ReplyToCommand()</tt>, which will automatically print your message either as a chat message or to the client's console, depending on the source of the command.

[[Category:SourceMod Scripting]]

{{LanguageSwitch}}

Category:SourceMod Scripting

2012-03-28T20:08:03Z

Azelphur:

This category contains articles about scripting for SourceMod with SourcePawn.

===Introductions===
*[[Introduction to SourceMod Plugins]] - Writing your "first plugin."
*[[Introduction to SourcePawn]] - Learning language syntax.
*[http://docs.sourcemod.net/api API Reference] - Searchable scripting API reference.

===Basic API===
*[[AutoConfigs (SourceMod Scripting)|AutoConfigs]] - Automatic .cfg creation for cvars.
*[[Commands (SourceMod Scripting)|Commands]] - Console commands/input.
*[[ConVars (SourceMod Scripting)|ConVars]] - Console variables (cvars).
*[[Events (SourceMod Scripting)|Events]] - Half-Life 2 Game Events.
*[[KeyValues (SourceMod Scripting)|KeyValues]] - KeyValues file parsing/writing.
*[[Menu API (SourceMod)|Menus]] - Building and drawing menus.
*[[SQL (SourceMod Scripting)|SQL]] - Using databases (MySQL, SQLite).
*[[Timers (SourceMod Scripting)|Timers]] - Timed callbacks.
*[[DataPacks|DataPacks]] - A good way to store asynchronous data.
*[[Translations (SourceMod Scripting)|Translations]] - Internationalization.
*[[Entity References (SourceMod)|Entity References]] - A safe way of storing entities.

===Advanced API===
*[[Admin API (SourceMod)|Administration API]] - Using the Admin Cache.
*[[Admin Menu (SourceMod Scripting)|Admin Menu API]] - Attaching to the Admin Menu.
*[[Creating Natives (SourceMod Scripting)|Creating Natives]] - Exposing API to other plugins.
*[[Function Calling API (SourceMod Scripting)|Function Calling API]] - Calling external functions.
*[[Optional Requirements (SourceMod Scripting)|Optional Requirements]] - Managing dependencies.
*[[SDKTools (SourceMod Scripting)|SDKTools]] - Using the powerful SDK abstraction layer.
*[[TempEnts (SourceMod SDKTools)|Temporary Entities]] - Using temporary entities.

===Information===
*[[Format Class Functions (SourceMod Scripting)|Format Class Functions]] - All about text formatting.
*[[Handles (SourceMod Scripting)|Handles]] - Overview of Handles and some common types.
*[[Optimizing Plugins (SourceMod Scripting)|Optimizing Plugins]] - Optimization hints.
*[[Tags (Scripting)|Tags]] - All about tags.
*[[Vectors Explained (Scripting)|Vectors Explained]] - Explanation of Vector types.

===Resources===
*[http://docs.sourcemod.net/api API Reference] - Searchable scripting API reference.
*[[Entity Properties]] - Explanation of Source entity properties.
*[[Game Events (Source)|Game Events]] - Game events listings for popular mods.
*[[Mod TempEnt List (Source)|Temp Entity Lists]] - Temporary entities for popular mods.
*[[SourceMod Profiler]] - Performance tracking and optimizing.
*[[Vice_keys]] - Decryption keys for ctx files
*[[Weapon Names(Source)]] - Weapon Names / weapon entity names
[[Category:SourceMod]]
[[Category:SourceMod Development]]

Timers (SourceMod Scripting)

2010-07-15T00:33:54Z

Azelphur: You need to CreateDataPack() before you can WritePack*

Timers in [[SourceMod]] are timed events that occur once or repeatedly at a given interval.

=Introduction=
Timers allow you to set an interval, a function to use as the event callback, and an optional Handle to pass through the callback. This is useful for saving data asynchronously.

All timer functions are in <tt>plugins/include/timers.inc</tt>.

=Basic Usage=
==One-Time Timers==
One-time timers are timers that only execute once. An example of a one-time timer might look like:

<pawn>public OnPluginStart()
{
CreateTimer(5.0, LoadStuff)
}

public Action:LoadStuff(Handle:timer)
{
PrintToServer("Loading stuff!")
}</pawn>

This code will print "Loading stuff!" to the server console five seconds after the map loads. The return value has no meaning for one-time timers.

==Repeatable Timers==
Repeatable timers execute infinitely many times, once every interval. Based on the return value, they either continue or cancel.

For example, say you want to display a message five times, once every three seconds:
<pawn>
DoMessage()
{
CreateTimer(3.0, PrintMsg, _, TIMER_REPEAT)
}

public Action:PrintMsg(Handle:timer)
{
static NumPrinted = 0
if (NumPrinted++ >= 5)
{
PrintToServer("Warning! This is a message.")
NumPrinted = 0

return Plugin_Stop
}

return Plugin_Continue
}</pawn>

Note that <tt>Plugin_Stop</tt> stops the timer, and <tt>Plugin_Continue</tt> allows it to continue repeating.

=Passing Data=
==Simple Values==
As mentioned earlier, timers let you pass values on to the callback function. This value can be any type. For example, let's say we want to print a message to a player fifteen seconds after they connect. However, we want to cancel the timer if the player disconnects. Implementing this is very easy:

<pawn>#define MAX_PLAYERS 256

new Handle:WelcomeTimers[MAX_PLAYERS+1]

public OnClientPutInServer(client)
{
WelcomeTimers[client] = CreateTimer(15.0, WelcomePlayer, client)
}

public OnClientDisconnect(client)
{
if (WelcomeTimers[client] != INVALID_HANDLE)
{
KillTimer(WelcomeTimers[client])
WelcomeTimers[client] = INVALID_HANDLE
}
}

public Action:WelcomePlayer(Handle:timer, any:client)
{
PrintToConsole(client, "Welcome to the server!")
WelcomeTimers[client] = INVALID_HANDLE
}</pawn>

==Handles==
If you want to pass a Handle as a value, you have the option of using <tt>TIMER_HNDL_CLOSE</tt>, which will automatically call <tt>CloseHandle()</tt> for you once the timer dies.

==Data Packs==
Data packs are packable structures that can be used to hold asynchronous data (data that must be saved and unpacked for later). They are especially useful for timers, and thus there exists a helper function, called <tt>CreateDataTimer()</tt>, which creates a timer using a data pack handle. The handle is created and closed automatically for you.

The above example could be rewritten as:
<pawn>#define MAX_PLAYERS 256

new Handle:WelcomeTimers[MAX_PLAYERS+1]

public OnClientPutInServer(client)
{
new Handle:pack = CreateDataPack();
WelcomeTimers[client] = CreateDataTimer(15.0, WelcomePlayer, pack)
WritePackCell(pack, client)
WritePackString(pack, "Welcome to the server!")
}

public OnClientDisconnect(client)
{
if (WelcomeTimers[client] != INVALID_HANDLE)
{
KillTimer(WelcomeTimers[client])
WelcomeTimers[client] = INVALID_HANDLE
}
}

public Action:WelcomePlayer(Handle:timer, Handle:pack)
{
decl String:str[128]
new client

/* Set to the beginning and unpack it */
ResetPack(pack)
client = ReadPackCell(pack)
ReadPackString(pack, str, sizeof(str))

PrintToConsole(client, "%s", str)
WelcomeTimers[client] = INVALID_HANDLE
}</pawn>

=Notes=
==Accuracy==
The smallest possible interval is 0.1 seconds. Timers have high precision (floating point) but low accuracy, as the current time is based on the in-game tick count, not the system clock. This has two implications:
*If the server is paused (not ticking), timers will not run.
*The server will not always tick at an exact interval.

For example, a 1.234 second interval timer starting from time <tt>t</tt> might not tick until <tt>t+1.242</tt> at a tickrate of 66 ticks per second.

==Timer Death==
All timers are guaranteed to die either by:
*<tt>CloseHandle()</tt> being called (or on plugin unload);
*<tt>KillTimer()</tt> being called;
*<tt>Plugin_Stop</tt> being returned from a repeatable timer;
*<tt>TriggerTimer()</tt> being called on a one-time timer;
*Execution of a one-time timer finishes.

When a timer dies, if <tt>TIMER_HNDL_CLOSE</tt> is set, the Handle will always be closed with the permissions that <tt>CloseHandle()</tt> uses by default. Since timers cannot be cloned, there should be no ownership issues.

==Changing Intervals==
The interval of a timer cannot be changed as of this writing. The timer must be killed and a new one created.

==AMX Mod X==
Unlike [[AMX Mod X]]'s <tt>set_task</tt> function, you cannot pass arrays using <tt>CreateTimer</tt>. To accomplish this, you should use the data pack functionality explained above.

Similarly, there are no flags for counted repeats (non-infinite loops) or timers based on the map start or end. These must be done manually.

=External Links=
*[http://www.sourcemod.net/devlog/?p=130 On Timer Design, Part 3] (SourceMod DevLog)
*[http://www.sourcemod.net/devlog/?p=119 On Timer Design, Part 2] (SourceMod DevLog)
*[http://www.sourcemod.net/devlog/?p=118 On Timer Design, Part 1] (SourceMod DevLog)

[[Category:SourceMod Scripting]]

{{LanguageSwitch}}