Left 4 Voting 2

2021-11-15T17:52:46Z

ReCreator: Example plugin corrections: added timer for vote end(it was endless if someone doesn't vote),а fixed number of voters replaced via max players number, fixed bug when 1 player could vote unlimited number of times, corrected VoteFailed user msg to VoteFail

Left 4 Dead 2 has a VGUI voting system controller by a bunch of Events and UserMessages. You can use either a string from the resource file, or L4D_TargetID_Player which will let you create any vote you want.

== How voting works ==
# A client issues a callvote with the vote type and argument.
# The VoteStart User Message is sent.
# Clients use the "Vote" command to register their votes ("Yes" or "No"), after which the server sends a VoteRegistered UserMessage to that player to acknowledge their vote. A vote_changed event is sent to all players with updated numbers.
# When the vote is complete, the server sends either a VotePass or VoteFail UserMessage.

== Server Entity ==

The server should update this as appropriate. Unfortunately, the valid values for m_iActiveIssueIndex is unknown.

{{begin-hl2msg|vote_controller (CVoteController)|string}}
{{hl2msg|int|m_activeIssueIndex|Number of the active issue}}
{{hl2msg|int|m_onlyTeamToVote|Corresponds to VoteStart's team argument.}}
{{hl2msg|int|m_votesYes|Current Yes votes}}
{{hl2msg|int|m_votesNo|Current No votes}}
{{hl2msg|int|m_potentialVotes|Number of players eligible to vote}}
{{end-hl2msg}}

== Console Commands ==

=== Vote ===

{{qnotice|This command is only valid when a vote is ongoing.}} 
{{begin-hl2msg|Vote|string}}
{{hl2msg|string|option|"Yes" or "No"}}
{{end-hl2msg}}

== User Messages ==
{{qnotice|These user messages use unsigned bytes for the team number. Since Valve represents no team as -1, no team is instead represented as its two's complement, 255.}} 

===VoteStart===
{{qnotice|Sent to all players in the vote group, corresponding with teams. The default implementation also sends it to bots.}} 

{{begin-hl2msg|VoteStart|string}}
{{hl2msg|byte|team|Team index or 255 for all}}
{{hl2msg|byte|initiator|Client index (NOT USERID) of person who started the vote, or 99 for the server.}}
{{hl2msg|string|issue|Vote issue translation string}}
{{hl2msg|string|param1|Vote issue text}}
{{hl2msg|string|initiatorName|Name of person who started the vote}}
{{end-hl2msg}}
====Values for "issue" and "param1" in standard votes====
{| class="wikitable"
|-
! Vote type !! issue !! param1
|-
| Kick || #L4D_vote_kick_player || Nickname of the person to be kicked without "#"
|-
| ReturnToLobby || #L4D_vote_return_to_lobby ||
|-
| ChangeCampaign || #L4D_vote_mission_change || #L4D360UI_CampaignName_C5
|-
| RestartChapter || #L4D_vote_passed_versus_level_restart ||
|-
| ChangeDifficulty (easy) || #L4D_vote_change_difficulty || #L4D_DifficultyEasy
|-
| ChangeDifficulty (hard) || #L4D_vote_change_difficulty || #L4D_DifficultyHard
|-
| Alltalk On || #L4D_vote_alltalk_change || #L4D_vote_alltalk_enable
|-
| Alltalk Off || #L4D_vote_alltalk_change || #L4D_vote_alltalk_disable
|}
*Campaigns aren't specified by map name but by the index the campaign's entry has in the game menus. Example: "5" specifies the campaign "The Parish"

===VoteRegistered===
{{qnotice|Only sent to player who voted}} 
{{begin-hl2msg|VoteRegistered|string}}
{{hl2msg|byte|vote|0 for No, 1 for Yes}}
{{end-hl2msg}}

===VotePass===
{{qnotice|Sent to all players after a vote passes.}} 

{{begin-hl2msg|VotePass|string}}
{{hl2msg|byte|team|Team index or 255 for all}}
{{hl2msg|string|details|Vote success translation string}}
{{hl2msg|string|param1|Vote winner}}
{{end-hl2msg}}

===VoteFail===
{{qnotice|Sent to all players after a vote fails.}} 

{{begin-hl2msg|VoteFail|string}}
{{hl2msg|byte|team|Team index or 255 for all}}
{{end-hl2msg}}

== Events ==
{{qnotice|team is -1 when sent to all players)}} 

=== vote_changed ===
{{begin-hl2msg|vote_changed|string}}
{{hl2msg|byte|yesVotes|}}
{{hl2msg|byte|noVotes|}}
{{hl2msg|byte|potentialVotes|}}
{{end-hl2msg}}
== Example voting plugin ==
This is a basic plugin that starts a vote, "Is gaben fat?". It does not ensure the same client does not vote multiple times, nor does it actually kick the user.

<sourcepawn>#include <sourcemod>

#define L4D2_TEAM_ALL -1

int g_iYesVotes;
int g_iNoVotes;
int g_iPlayersCount;
bool VoteInProgress;
bool CanPlayerVote[MAXPLAYERS + 1];

public void OnPluginStart()
{
RegConsoleCmd("testvote", Callvote_Handler);
RegConsoleCmd("Vote", vote);
}

public Action Callvote_Handler(int client, int args)
{
BfWrite bf = UserMessageToBfWrite(StartMessageAll("VoteStart", USERMSG_RELIABLE));

bf.WriteByte(L4D2_TEAM_ALL);
bf.WriteByte(0);
bf.WriteString("#L4D_TargetID_Player");
bf.WriteString("Is gaben fat?");
bf.WriteString("Server");
EndMessage();

g_iYesVotes = 0;
g_iNoVotes = 0;
g_iPlayersCount = 0;
VoteInProgress = true;

for(int i = 1; i <= MaxClients; i++)
{
if(IsValidClient(i) && !IsFakeClient(i))
{
CanPlayerVote[i] = true;
g_iPlayersCount ++;
}
}

UpdateVotes();
CreateTimer(10.0, Timer_VoteCheck, TIMER_FLAG_NO_MAPCHANGE);

return Plugin_Handled;
}
public Action Timer_VoteCheck(Handle timer)
{
if(VoteInProgress)
{
VoteInProgress = false;
UpdateVotes();
}
}

public void UpdateVotes()
{
Event event = CreateEvent("vote_changed");
event.SetInt("yesVotes", g_iYesVotes);
event.SetInt("noVotes", g_iNoVotes);
event.SetInt("potentialVotes", g_iPlayersCount);
event.Fire();

if ((g_iYesVotes + g_iNoVotes == g_iPlayersCount) || !VoteInProgress)
{
PrintToServer("voting complete!");

for(int i = 1; i <= MaxClients; i++)
{
if(IsValidClient(i) && !IsFakeClient(i))
{
CanPlayerVote[i] = false;
}
}

VoteInProgress = false;

if (g_iYesVotes > g_iNoVotes)
{
BfWrite bf = UserMessageToBfWrite(StartMessageAll("VotePass"));
bf.WriteByte(L4D2_TEAM_ALL);
bf.WriteString("#L4D_TargetID_Player");
bf.WriteString("Gaben is fat");
EndMessage();
}
else
{
BfWrite bf = UserMessageToBfWrite(StartMessageAll("VoteFail"));
bf.WriteByte(L4D2_TEAM_ALL);
EndMessage();
}
}
}

public Action vote(int client, int args)
{
if(VoteInProgress && CanPlayerVote[client] == true)
{
char arg[8];
GetCmdArg(1, arg, sizeof arg);

PrintToServer("Got vote %s from %i", arg, client);

if (strcmp(arg, "Yes", true) == 0)
{
g_iYesVotes++;
}
else if (strcmp(arg, "No", true) == 0)
{
g_iNoVotes++;
}

UpdateVotes();
}

return Plugin_Continue;
}

stock bool IsValidClient(int client){
return (client > 0 && client <= MaxClients && IsClientInGame(client));
}
</sourcepawn>

==See Also==
* [[Left 4 Voting]]
* [[TF2 Voting]]
* [https://forums.alliedmods.net/showthread.php?t=162164 BuiltinVotes], a SourceMod extension that exposes a voting API that uses this voting system.

AlliedModders Wiki - User contributions [en]

Left 4 Voting 2