ConVars (SourceMod Scripting)

From AlliedModders Wiki
Revision as of 12:10, 5 February 2009 by GH0sTy (talk | contribs) (Finding ConVars)
Jump to: navigation, search

ConVars are console variables. They store string, float, or numerical values. These values can be changed via the console or .cfg files, and sometimes even persist across server sessions.

Introduction

ConVars are accessed through Handles. There are two ways to obtain a ConVar Handle. You can either create a new ConVar, or find an existing one. If you create a ConVar that already exists, it will automatically re-use the old one.

Note: ConVar Handles are unique to the ConVar, and do not need to be freed or "uncreated." They exist until SourceMod is unloaded.

Finding ConVars

Finding ConVars is very simple. For example, let's say you want to use mp_startmoney from Counter-Strike:Source:

new Handle:g_hStartMoney
 
public OnPluginStart()
{
	g_hStartMoney = FindConVar("mp_startmoney")
}

Note: FindConVar() will return INVALID_HANDLE if the ConVar is not found. Keep this in mind if you are trying to read ConVars from other plugins.

Creating ConVars

A simple ConVar only requires two parameters, a name and a default value. However, it's a good idea to include a description:

new Handle:g_hEnabled
 
public OnPluginStart()
{
	g_hEnabled = CreateConVar("myplugin_enabled", "1", "Sets whether my plugin is enabled")
}

You can also specify value constraints. For example, let's create a cvar called myplugin_ratio which cannot go above 1.0 or below 0.1.

new Handle:g_hEnabled
 
public OnPluginStart()
{
	g_hEnabled = CreateConVar("myplugin_ratio",
			"0.6",
			"Sets a vote ratio",
			_,	/* Flags will be discussed later */
			true,	/* Has a minimum */
			0.1,
			true,	/* Has a maximum */
			1.0)
}

The default value can be any type of data, and it does not restrict future data types that can be used. However, the minimum and maximum constraints always interpret the value as a float.

If you create a ConVar that already exists, you will receive a Handle to that ConVar. Furthermore, the Handle itself will be identical, as neither plugin will own the Handle. The description, default value, or constraints will not be changed.

Using/Changing Values

Managing ConVars is very simple. For example, let's say we want to change mp_startmoney, but save the old value and restore it later. Re-using our mp_startmoney code from FindConVar:

new g_oldmoney
 
SetStartMoney(newmoney)
{
	g_oldmoney = GetConVarInt(g_hStartMoney)
	SetConVarInt(g_hStartMoney, newmoney)
}
 
RestoreStartMoney()
{
	SetConVarInt(g_hStartMoney, g_oldmoney)
}

Although there are different functions for value types (float, string, et cetera), the internal data is always stored the same way. For example, this code will work:

public GetStartMoney()
{
	decl String:buffer[128]
 
	GetConVarString(g_hStartMoney, buffer, sizeof(buffer))
 
	return StringToInt(buffer)
}

Even though mp_startmoney is an integer, it can still be retrieved as a string.

Flags

ConVars can have a number of flags to change their behaviour. A few of the important flags are:

  • FCVAR_PROTECTED - Sensitive information (should not be exposed to clients or logs).
  • FCVAR_NOTIFY - Clients are notified of changes.
  • FCVAR_CHEAT - Can only be use if sv_cheats is 1.
  • FCVAR_REPLICATED - Setting is forced to clients.

Let's say we wanted to toggle whether a cvar had FCVAR_CHEAT. The following two functions could be used:

UnsetCheatVar(Handle:hndl)
{
	new flags = GetConVarFlags(hndl)
	flags &= ~FCVAR_CHEAT
	SetConVarFlags(hndl, flags)
}
 
SetCheatVar(Handle:hndl)
{
	new flags = GetConVarFlags(hndl)
	flags |= FCVAR_CHEAT
	SetConVarFlags(hndl, flags)
}

Change Callbacks

As of Half-Life 2, it is possible to know when ConVars change. While this is a very powerful feature, you must be careful not to set a ConVar inside a ConVar change hook such that it re-invokes he same callback. This results in infinite recursion.

For example, let's say you want to detect when bot_quota changes and to prevent it from going below 2:

new Handle:g_hBotQuota
 
public OnPluginStart()
{
	g_hBotQuota = FindConVar("bot_quota")
	if (g_hBotQuota != INVALID_HANDLE)
	{
		HookConVarChange(g_hBotQuota, OnBotQuotaChange)
	}
}
 
public OnBotQuotaChange(Handle:cvar, const String:oldVal[], const String:newVal[])
{
	if (StringToInt(newVal) < 2)
	{
		SetConVarInt(cvar, 2)
	}
}

Note 1: You do not need to explicitly unhook ConVarChange functions on shutdown. These hooks are removed when your plugin unloads.

Note 2: You cannot prevent cvar changes from happening; you can only change the value again. If the engine or game mod already have a change function installed for a ConVar, that function will always be called first.

Warning: This template (and by extension, language format) should not be used, any pages using it should be switched to Template:Languages

View this page in:  English  Russian  简体中文(Simplified Chinese)