Protobuf

From AlliedModders Wiki
Revision as of 09:04, 17 January 2013 by Psychonic (talk | contribs) (Multi-game usermessages example)
Jump to: navigation, search

Intro

Unlike the serial bitbuffer-backed usermessages in older games, newer games such as CS:GO (and DOTA 2) now use Google's Protocol Buffers or "protobuf" to back net messages and usermessages.

Differences

Instead of having to be read or written in order, the protobuf usermessages use defined fields, accessible by name, in any order.

Starting, ending, and hooking usermessages remains unchanged. Reading and writing values to/from them is done using the Pb* set of natives in protobuf.inc instead of the Bf* natives in bitbuffer.inc.

You can tell which usermessage system is in use for the current game by checking GetUserMessageFormat(). Possible returns are USERMSG_BITBUF and USERMSG_PROTOBUF.


Basic fields ("optional" or "required") are single values and use the PbRead*/PbSet* natives.

Repeated fields are arrays of values, accessible by their 0-based index with the PbReadRepeated* natives or added with the PbAdd* natives. You can get the count of values in a repeated field with PbGetRepeatedFieldCount.


See the CS:GO Usermessages as defined in protobuf's proto format.

Multi-game usermessages example

From funcommands' drug.sp, using the Fade usermessage:

	new clients[2];
	clients[0] = client;	
 
	new duration = 255;
	new holdtime = 255;
	new flags = 0x0002;
	new color[4] = { 0, 0, 0, 128 };
	color[0] = GetRandomInt(0,255);
	color[1] = GetRandomInt(0,255);
	color[2] = GetRandomInt(0,255);
 
	new Handle:message = StartMessageEx(g_FadeUserMsgId, clients, 1);
 
	if (GetUserMessageFormat() == USERMSG_PROTOBUF)
	{
		PbSetInt(message, "duration", duration);
		PbSetInt(message, "hold_time", holdtime);
		PbSetInt(message, "flags", flags);
		PbSetColor(message, "clr", color);
	}
	else
	{
		BfWriteShort(message, duration);
		BfWriteShort(message, holdtime);
		BfWriteShort(message, flags);
		BfWriteByte(message, color[0]);
		BfWriteByte(message, color[1]);
		BfWriteByte(message, color[2]);
		BfWriteByte(message, color[3]);
	}
 
	EndMessage();

Protobuf natives

TODO: replace this with a link to plugins/include/protobuf.inc once it is pushed to sourcemod-central.

/**
 * Reads an int32, uint32, sint32, fixed32, or sfixed32 from a protobuf message.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @return				Integer value read.
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native PbReadInt(Handle:pb, const String:field[]);
 
/**
 * Reads a float or downcasted double from a protobuf message.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @return				Float value read.
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native Float:PbReadFloat(Handle:pb, const String:field[]);
 
/**
 * Reads a bool from a protobuf message.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @return				Boolean value read.
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native bool:PbReadBool(Handle:pb, const String:field[]);
 
/**
 * Reads a string from a protobuf message.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @param buffer		Destination string buffer.
 * @param maxlength		Maximum length of output string buffer.
 * @noreturn
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native PbReadString(Handle:pb, const String:field[], String:buffer[], maxlength);
 
/**
 * Reads an RGBA color value from a protobuf message.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @param buffer		Destination color buffer.
 * @noreturn
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native PbReadColor(Handle:pb, const String:field[], buffer[4]);
 
/**
 * Reads an XYZ angle value from a protobuf message.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @param buffer		Destination angle buffer.
 * @noreturn
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native PbReadAngle(Handle:pb, const String:field[], Float:buffer[3]);
 
/**
 * Reads an XYZ vector value from a protobuf message.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @param buffer		Destination vector buffer.
 * @noreturn
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native PbReadVector(Handle:pb, const String:field[], Float:buffer[3]);
 
/**
 * Reads an XY vector value from a protobuf message.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @param buffer		Destination vector buffer.
 * @noreturn
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native PbReadVector2D(Handle:pb, const String:field[], Float:buffer[2]);
 
/**
 * Gets the number of elements in a repeated field of a protobuf message.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @return				Number of elements in the field.
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native PbGetRepeatedFieldCount(Handle:pb, const String:field[]);
 
/**
 * Reads an int32, uint32, sint32, fixed32, or sfixed32 from a protobuf message repeated field.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @param index			Index in the repeated field.
 * @return				Integer value read.
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native PbReadRepeatedInt(Handle:pb, const String:field[], index);
 
/**
 * Reads a float or downcasted double from a protobuf message repeated field.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @param index			Index in the repeated field.
 * @return				Float value read.
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native Float:PbReadRepeatedFloat(Handle:pb, const String:field[], index);
 
/**
 * Reads a bool from a protobuf message repeated field.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @param index			Index in the repeated field.
 * @return				Boolean value read.
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native bool:PbReadRepeatedBool(Handle:pb, const String:field[], index);
 
/**
 * Reads a string from a protobuf message repeated field.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @param index			Index in the repeated field.
 * @param buffer		Destination string buffer.
 * @param maxlength		Maximum length of output string buffer.
 * @noreturn
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native PbReadRepeatedString(Handle:pb, const String:field[], index, String:buffer[], size);
 
/**
 * Reads an RGBA color value from a protobuf message repeated field.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @param index			Index in the repeated field.
 * @param buffer		Destination color buffer.
 * @noreturn
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native PbReadRepeatedColor(Handle:pb, const String:field[], index, buffer[4]);
 
/**
 * Reads an XYZ angle value from a protobuf message repeated field.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @param index			Index in the repeated field.
 * @param buffer		Destination angle buffer.
 * @noreturn
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native PbReadRepeatedAngle(Handle:pb, const String:field[], index, Float:buffer[3]);
 
/**
 * Reads an XYZ vector value from a protobuf message repeated field.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @param index			Index in the repeated field.
 * @param buffer		Destination vector buffer.
 * @noreturn
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native PbReadRepeatedVector(Handle:pb, const String:field[], index, Float:buffer[3]);
 
/**
 * Reads an XY vector value from a protobuf message repeated field.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @param index			Index in the repeated field.
 * @param buffer		Destination vector buffer.
 * @noreturn
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native PbReadRepeatedVector2D(Handle:pb, const String:field[], index, Float:buffer[2]);
 
/**
 * Sets an int32, uint32, sint32, fixed32, or sfixed32  on a protobuf message.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @param value			Integer value to set.
 * @noreturn
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native PbSetInt(Handle:pb, const String:field[], value);
 
/**
 * Sets a float or double on a protobuf message.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @param value			Float value to set.
 * @noreturn
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native PbSetFloat(Handle:pb, const String:field[], Float:value);
 
/**
 * Sets a bool on a protobuf message.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @param value			Boolean value to set.
 * @noreturn
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native PbSetBool(Handle:pb, const String:field[], bool:value);
 
/**
 * Sets a string on a protobuf message.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @param value			String value to set.
 * @noreturn
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native PbSetString(Handle:pb, const String:field[], const String:value[]);
 
/**
 * Sets an RGBA color on a protobuf message.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @param value			Color value to set.
 * @noreturn
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native PbSetColor(Handle:pb, const String:field[], const color[4]);
 
/**
 * Sets an XYZ angle on a protobuf message.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @param value			Angle value to set.
 * @noreturn
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native PbSetAngle(Handle:pb, const String:field[], const Float:angle[3]);
 
/**
 * Sets an XYZ vector on a protobuf message.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @param value			Vector value to set.
 * @noreturn
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native PbSetVector(Handle:pb, const String:field[], const Float:vec[3]);
 
/**
 * Sets an XY vector on a protobuf message.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @param value			Vector value to set.
 * @noreturn
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native PbSetVector2D(Handle:pb, const String:field[], const Float:vec[2]);
 
/**
 * Add an int32, uint32, sint32, fixed32, or sfixed32 to a protobuf message repeated field.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @param value			Integer value to add.
 * @noreturn
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native PbAddInt(Handle:pb, const String:field[], value);
 
/**
 * Add a float or double to a protobuf message repeated field.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @param value			Float value to add.
 * @noreturn
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native PbAddFloat(Handle:pb, const String:field[], Float:value);
 
/**
 * Add a bool to a protobuf message repeated field.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @param value			Boolean value to add.
 * @noreturn
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native PbAddBool(Handle:pb, const String:field[], bool:value);
 
/**
 * Add a string to a protobuf message repeated field.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @param value			String value to add.
 * @noreturn
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native PbAddString(Handle:pb, const String:field[], const String:value[]);
 
/**
 * Add an RGBA color to a protobuf message repeated field.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @param value			Color value to add.
 * @noreturn
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native PbAddColor(Handle:pb, const String:field[], const color[4]);
 
/**
 * Add an XYZ angle to a protobuf message repeated field.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @param value			Angle value to add.
 * @noreturn
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native PbAddAngle(Handle:pb, const String:field[], const Float:angle[3]);
 
/**
 * Add an XYZ vector to a protobuf message repeated field.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @param value			Vector value to add.
 * @noreturn
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native PbAddVector(Handle:pb, const String:field[], const Float:vec[3]);
 
/**
 * Add an XY vector to a protobuf message repeated field.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @param value			Vector value to add.
 * @noreturn
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */
native PbAddVector2D(Handle:pb, const String:field[], const Float:vec[2]);
 
/**
 * Retrieve a handle to an embedded protobuf message in a protobuf message.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @return				protobuf handle to embedded message.
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */ 
native Handle:PbReadMessage(Handle:pb, const String:field[]);
 
/**
 * Retrieve a handle to an embedded protobuf message in a protobuf message repeated field.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @param index			Index in the repeated field.
 * @return				protobuf handle to embedded message.
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */ 
native Handle:PbReadRepeatedMessage(Handle:pb, const String:field[], index);
 
/**
 * Adds an embedded protobuf message to a protobuf message repeated field.
 *
 * @param pb			protobuf handle.
 * @param field			Field name.
 * @return				protobuf handle to added, embedded message.
 * @error				Invalid or incorrect Handle, non-existant field, or incorrect field type.
 */ 
native Handle:PbAddMessage(Handle:pb, const String:field[]);