Ru:Commands (SourceMod Scripting)

SourceMod позволяет создать вам консольные команды, похожие на AMX Mod X. Есть два главных вида консольных команд:

• Серверные команды - Срабатывают с одним из следующих способов ввода:
  • С помощью консоли сервера
  • С помощью удаленной консоли (RCON)
  • Функция ServerCommand(), либо из SourceMod либо Half-Life 2 движка
• Консольные команды - Срабатывают с одним из следующих способов ввода:
  • С помощью консоли клиента
  • Любой из методов ввода серверных команд

Для серверных команд не существует клиентского индекса. Для консольных/клиентских команд, существует клиентский индекс, но он может быть 0, чтобы показать, что команда с сервера.

Обратите внимание, что кнопка-бинд "commands", такие как +attack и +duck, они не консольные команды. Эти команды отдельно передаются, посколько они отдельно привязаны.

Серверные команды

Как отмечалось выше, серверные команды срабатывают через консоль сервера, будь то удалённую, локальную, или через движок Source. Индекс клиента не связан с серверными командами.

Серверные команды регистрируются через RegServerCmd() функцию, расположенную в console.inc. При регистрации команды, вы можете записать поверх существующей команды, и таким образом, возвращаемое значение становится важным.

• Plugin_Continue - The original server command will be processed, if there was one. Если серверная команда создана плагином, здесь не будет эффекта.
• Plugin_Handled - The original server command will not be processed, if there was one. Если серверная команда создана плагином, здесь не будет эффекта.
• Plugin_Stop - The original server command will not be processed, if there was one. Additionally, no further hooks will be called for this command until it is fired again.

Добавление серверных команд

Допустим, мы хотим добавить тестовую команду, чтобы показать как Half-Life 2 вычисляет аргументы команды. Вот возможная реализация:

public void OnPluginStart()
{
	RegServerCmd("test_command", Command_Test)
}
 
public Action Command_Test(int args)
{
	char arg[128]
	char full[256]
 
	GetCmdArgString(full, sizeof(full))
 
	PrintToServer("Строка аргумента: %s", full)
	PrintToServer("Количество аргументов: %d", args)
	for (int i = 1; i <= args; i++)
	{
		GetCmdArg(i, arg, sizeof(arg))
		PrintToServer("Аргумент %d: %s", i, arg)
	}
}

Блокирование серверных команд

Допустим мы хотим отключить "kickid" команду на сервере. Нет причин делать это, но для примера сойдет:

public void OnPluginStart()
{
	RegServerCmd("kickid", Command_KickId)
}
 
public Action Command_Kickid(int args)
{
	return Plugin_Handled
}

Консольные команды

В отличие от серверных команд, консольные могут быть вызваны, как сервером, так и клиентом, так что callback функция получает клиентский индекс, а также количество аргументов. Если сервер использовал команду, клиентский индекс будет 0.

When returning the Action from the callback, the following effects will happen:

• Plugin_Continue: The original functionality of the command (if any) will still be processed. If there was no original functionality, the client will receive "Unknown command" in their console.
• Plugin_Handled: The original functionality of the command (if any) will be blocked. If there was no functionality originally, this prevents clients from seeing "Unknown command" in their console.
• Plugin_Stop: Same as Plugin_Handled, except that this will be the last hook called.

Обратите внимание, в отличие от AMX Mod X, SourceMod не сможет зарегистрировать командные фильтры. т.е. нет эквивалента этой команды:

register_clcmd("say /ff", "Command_SayFF");

Это было удаленно, чтобы сделать наш код проще и быстрее. Написание такого же функционала легче и показано ниже.

Добавление команд

Создать клиентские команды очень просто. Давайте переделаем нашу тест команду, чтобы можно было отобразить информацию о клиенте.

public void OnPluginStart()
{
	RegConsoleCmd("test_command", Command_Test)
}
 
public Action Command_Test(int client, int args)
{
	char arg[128]
	char full[256]
 
	GetCmdArgString(full, sizeof(full))
 
	if (client)
	{
		char name[32]
		GetClientName(client, name, sizeof(name))
		PrintToServer("Команда от клиента: %s", name)
	} else {
		PrintToServer("Команда от сервера.")
	}
 
	PrintToServer("Строка аргументов: %s", full)
	PrintToServer("Количество аргументов: %d", args)
	for (int i = 1; i <= args; i++)
	{
		GetCmdArg(i, arg, sizeof(arg))
		PrintToServer("Аргумент %d: %s", i, arg)
	}
}

Захват команд

Пример: захват типичной команды say. Let's say we want to tell players whether FF is enabled when they say '/ff' in game.

Before we implement this, a common point of confusion with the 'say' command is that Half-Life 2 (and Half-Life 1), by default, send it with the text in one big quoted string. This means if you say "I like hot dogs," your command will be broken down as such:

• Argument string: "I like hot dogs"
• Argument count: 1
• Argument #1: I like hot dogs

However, if a player types this in their console: say I like yams, it will be broken up as:

• Argument string: I like yams
• Argument count: 3
• Argument #1: I
• Argument #2: like
• Argument #3: yams

Thus, to take into account both of these situations, we are going to use GetCmdArgString and manually parse the input.

public void OnPluginStart()
{
	RegConsoleCmd("say", Command_Say)
}
 
public Action Command_Say(int client, int args)
{
	char text[192]
	GetCmdArgString(text, sizeof(text))
 
	int startidx = 0
	if (text[0] == '"')
	{
		startidx = 1
		/* Лишаем ковычки от окончания, если есть */
		int len = strlen(text);
		if (text[len-1] == '"')
		{
			text[len-1] = '\0'
		}
	}
 
	if (StrEqual(text[startidx], "/ff"))
	{
		Handle ff = FindConVar("mp_friendlyfire")
		if (GetConVarInt(ff))
		{
			PrintToConsole(client, "Огонь по товарищам включен.")
		} else {
			PrintToConsole(client, "Огонь по товарищам выключен.")
		}
		/* Блокирование сообщения клиента от вещания */
		return Plugin_Handled
	}
 
	/* Пусть работает как обычно */
	return Plugin_Continue
}

Создание Админской команды

Давайте создадим простую админскую команду, которая позволяет кикнуть игрока, по его полному имени.

public void OnPluginStart()
{
	RegAdminCmd("admin_kick",
		Command_Kick,
		ADMFLAG_KICK,
		"Кикает игрока по нику")
}
 
public Action Command_Kick(int client, int args)
{
	if (args < 1)
	{
		PrintToConsole(client, "Использование: admin_kick <ник>")
		return Plugin_Handled
	}
 
	char name[32]
        int maxplayers, target = -1
	GetCmdArg(1, name, sizeof(name))
 
	maxplayers = GetMaxClients()
	for (int i = 1; i <= maxplayers; i++)
	{
		if (!IsClientConnected(i))
		{
			continue
		}
		char other[32]
		GetClientName(i, other, sizeof(other))
		if (StrEqual(name, other))
		{
			target = i
		}
	}
 
	if (target == -1)
	{
		PrintToConsole(client, "Не могу найти игрока с ником: \"%s\"", name)
		return Plugin_Handled
	}
 
	ServerCommand("kickid %d", GetClientUserId(target));
 
	return Plugin_Handled
}

Иммунитет

В нашем прошлом примере, мы не сделали иммунитет. Иммунитет является гораздно сложной системой в SourceMod, чем это было в AMX Mod X, и не существует просто флага, чтобы обозначить его. Вместо, этого существует две функции:

• CanAdminTarget: Проверяет исходные значения AdminId для иммунитета.
• CanUserTarget: Проверяет внутриигровых клиентов для иммунитета.

While immunity is generally tested player versus player, it is possible you might want to check for immunity and not have a targetting client. While there is no convenience function for this yet, a good idea might be to check for either default or global immunity on the player's groups (these can be user-defined for non-player targeted scenarios).

When checking for immunity, the following heuristics are performed in this exact order:

1. If the targeting AdminId is INVALID_ADMIN_ID, targeting fails.
2. If the targetted AdminId is INVALID_ADMIN_ID, targeting succeeds.
3. If the targeting admin has Admin_Root (ADMFLAG_ROOT), targeting succeeds.
4. If the targetted admin has global immunity, targeting fails.
5. If the targetted admin has default immunity, and the targeting admin belongs to no groups, targeting fails.
6. If the targetted admin has specific immunity from the targeting admin via group immunities, targeting fails.
7. If no conclusion is reached via the previous steps, targeting succeeds.

So, how can we adapt our function about to use immunity?

public Action Command_Kick(int client, int args)
{
	if (args < 1)
	{
		PrintToConsole(client, "Использование: admin_kick <ник>")
		return Plugin_Handled
	}
 
	char name[32]
        int maxplayers, target = -1
	GetCmdArg(1, name, sizeof(name))
 
	maxplayers = GetMaxClients()
	for (int i = 1; i <= maxplayers; i++)
	{
		if (!IsClientConnected(i))
		{
			continue
		}
		char other[32]
		GetClientName(i, other, sizeof(other))
		if (StrEqual(name, other))
		{
			target = i
		}
	}
 
	if (target == -1)
	{
		PrintToConsole(client, "Не могу найти игрока с ником: \"%s\"", name)
		return Plugin_Handled
	}
 
	if (!CanUserTarget(client, target))
	{
		PrintToConsole(client, "Вы не можете использовать этого клиента как цель.")
		return Plugin_Handled
	}
 
	ServerCommand("kickid %d", GetClientUserId(target))
 
	return Plugin_Handled
}

Только клиентские команды

SourceMod exposes a forward that is called whenever a client executes any command string in their console, called OnClientCommand. An example of this looks like:

public Action OnClientCommand(int client, int args)
{
	char cmd[16]
	GetCmdArg(0, cmd, sizeof(cmd));	/* Получаем название команды */
 
	if (StrEqual(cmd, "test_command"))
	{
		/* Получаем клиентскую команду! Блокируем её... */
		return Plugin_Handled
	}
 
	return Plugin_Continue
}

It is worth noting that not everything a client sends will be available through this command. Command registered via external sources in C++ may not be available, especially if they are created via CON_COMMAND in the game mod itself. For example, "say" is usually implemented this way, because it can be used by both clients and the server, and thus it does not channel through this forward.

Чат триггеры

SourceMod будет автоматически создавать чат триггеры для каждой команды, которую вы сделали (по ревизии 900). Для примера, если вы создали консольную команду "sm_megaslap", администраторы смогут набрать ее и в say/say_team режимах:

!sm_megaslap
!megaslap
/sm_megaslap
/megaslap

SourceMod будет выполнять эту команду и ее аргументы, как если бы она пришла из консоли клиента.

• "!" является публичным триггером по умолчанию (PublicChatTrigger в configs/core.cfg) и ваша команда будет отображена всем клиентам.
• "/" является скрытым триггером по умолчанию (SilentChatTrigger в configs/core.cfg) и ваша команда не будет показана остальным клиентам

SourceMod будет исполнять только те команды, которые зарегистрированы с RegConsoleCmd или RegAdminCmd, и только если эти команды уже не используются Half-life 2 движком или другим игровым модом. Если команда идет с префиксом "sm_", то "sm_" можно исключить, из написания в чате.

Консольные команды, которые хотят поддерживать использование в качестве триггера чата, не должны использовать нативы вроде PrintTo*. Вместо этого, они должны использовать ReplyToCommand(), которая будет автоматически печатать ваше сообщение либо в виде сообщения чата либо в виде консоли клиента, в зависимости от источника команды.